Texto para Colunas

Resolvendo o problema

1. Declaramos as variáveis e encontramos a última linha para realizarmos um loop

   Dim UltLinha As Long
   Dim i As Integer
   
   UltLinha = Cells(Rows.Count, 1).End(xlUp).Row
   

2. Iremos usar a opção de texto para colunas dentro do loop e acabaremos por subscrever alguns dados. Por isto, desativamos os alertas do Excel para evitar que a cada iteração recebamos um alerta (lembre-se de ativa-lo novamente ao final do loop).

   Application.DisplayAlerts = False
   

3. Criamos o loop For Next até a ultima linha e utilizamos o método TextToColumns. Como os dados do problema aparecem separados pelo traço (-) configuramos este critério para separação dos dados nas colunas.

   For i = 4 To UltLinha
       Cells(i, 1).TextToColumns Destination:=Cells(i, 3), DataType:=xlDelimited, Other:=True, OtherChar:="-"
   

4. O Excel entende os parenteses () do ddd como número negativo. Sendo assim, utilizamos a função Abs para considerar apenas valor absoluto.

   Cells(i, 4).Value = Abs(Cells(i, 4).Value)
   

5. Agrupamos as duas partes do telefone, que estavam divididas pelo traço em uma única célula, e deslocamos o nome para a célula que fica vazia onde tinha a segunda parte do telefone.

   Cells(i, 5).Value = Cells(i, 5).Value & Cells(i, 6).Value
   Cells(i, 6).Value = Cells(i, 7).Value
   

6. Calculamos o valor a pagar multiplicando os pulsos pelo custo (que foi dado no enunciado do problema). Tornamos as letras do nome próprio maiúsculas com a função StrConv e o argumento vbProperCase

       Cells(i, 7).Value = Cells(i, 3) * 1.3
       Cells(i, 6).Value = StrConv(Cells(i, 6), vbProperCase)
   Next i
   

Código Consolidado

Sub Resolucao()

    Dim UltLinha As Long
    Dim i As Integer

    UltLinha = Cells(Rows.Count, 1).End(xlUp).Row

    Application.DisplayAlerts = False

    For i = 4 To UltLinha

        Cells(i, 1).TextToColumns Destination:=Cells(i, 3), DataType:=xlDelimited, Other:=True, OtherChar:="-"
        Cells(i, 4).Value = Abs(Cells(i, 4).Value)
        Cells(i, 5).Value = Cells(i, 5).Value & Cells(i, 6).Value
        Cells(i, 6).Value = Cells(i, 7).Value
        Cells(i, 7).Value = Cells(i, 3) * 1.3
        Cells(i, 6).Value = StrConv(Cells(i, 6), vbProperCase)

    Next i

    Application.DisplayAlerts = True

End Sub